;一番下にキー割当の変更を含めたミニ解説があります。

#IfWinActive, Company Of Heroes 2	;CoH2上でのみ有効
#SingleInstance ignore				;2つ以上の起動を無効化
SetTitleMatchMode, 3

;==スクリプトの制御==================
+Alt::Suspend,On		;[Shift+Alt]	このスクリプトを無効化。テキストを書きたい時に押す
~Alt::Suspend,Off		;[Alt]			このスクリプトを有効化
~Enter::Suspend,On		;[Enter]		このスクリプトを無効化。チャットを開始する際に押す
+~Enter::Suspend,Off	;[Shift+Enter]	このスクリプトを有効化。チャットを確定する際に押す
~RShift::Reload			;[右Shift]		このスクリプトの再読み込み
;=================================


;==部隊選択(ナンバリング)=============
q::7			;1〜6、QWRTがナンバリングとして使用可能
w::8
r::9
t::0
;=================================


;==メイン==========================
+g::send,re		;[Shift+G] 修理/OKW・ソ連ATグレ/ソ連特殊手榴弾/ライグレ/結束手榴弾/サッチェル/トミー砲撃要請/M20・M4・AEC煙幕/MTカウンター砲撃/ラミング/T-70リコン/オーバードライブ/Ober煙幕手榴弾/AimedShot/ShellShock/少佐撤退先/Supervise/ファイアフライロケット/AVRE発射/OKW将校TargetThem
^g::send,f 		;[Ctrl+G]  Pファウスト/AP弾/煙幕手榴弾/戦車煙幕弾/フレア/SU-85フォーカスサイト/クルーリペア/英軍ガモンボム/MG焼夷弾/少佐航空偵察/トミー砲撃/OKW将校ForceRetreat/JegerLightInfスプリント

^f::send,hko	;[Ctrl+F]  HoldFire/PrioritizeVehicles/ハンドブレーキ/ウラー/トミー回復/集中砲撃/少佐偽砲撃/サルベージ/OKW工兵地雷探知機トグル
^d::send,d		;[Ctrl+D]  建物・乗り物から出る/手榴弾/燃焼手榴弾/ショック煙幕手榴弾/デモリッション/救急車設置/HitTheDirt/AECTargetThread/英軍エンジ障害物爆破/ゴリアテ爆破
^s::send,np		;[Ctrl+S]  米軍ATグレ/スプリント/スタングレネード/英戦車手榴弾/OnMe!/トリップワイヤー/ブービートラップ
^c::send,c		;[Ctrl+C]  ATGカモフラージュ/煙幕手榴弾/デモリッション/InfiltrationGre/スモークスクリーン/モータースモーク弾/米クリティカルリペア/英砂クリティカルショット/OfficerCharge/戦車セキュアモード

+v::send,v		;[Shift+V] モロトフ/M36AP弾/FlankingSpeed/MedicalSupply
^v::send,{r 5}	;[Ctrl+V]  選択中の歩兵全補充
+a::send,g		;[Shift+A] Attackground
^e::send,u		;[Ctrl+E]  後退走行
y::t			;[Y] リトリート/米軍クルー降車/PanzerTactician/米ATG視界射程延長
g::s			;[G] Stop/建物内のHMGの方向を自動化
h::w			;[H] 米ATG貫通力Up/TargetWeakPoint/白燐弾/EmergencyWarSpeed/Brace
v::r			;[V] 補充/生産施設建設メニュー
;b::b			;[B] 建設メニュー/砲撃/BlitzTactics/CombatBlit
;a::a			;[A] AttackMove/建物内のHMGの方向を変える
^x::send,x		;[Ctrl+X] 英軍デモリッション/サッチェル(対車両粘着)/コンスクリプト修理
z::send,zm		;[Z] コンスマージ/米軍煙幕手榴弾/戦車弾切替/M20地雷/英軍迫撃砲陣地&HQカウンター砲撃/FFエイド

^b::			;[Ctrl+B]  FuelCache
  send,v
  sleep,100
  send,f
  return
+b::			;[Shift+B] MunitionsCache
  send,v
  sleep,100
  send,m
  return
;=================================


;==トラップ=========================
+e::			;[Shift+E] ワイヤー、土嚢
  send,b
  sleep,100
  send,w
  return
+d::			;[Shift+D] 土嚢,タンクトラップ
  send,b
  sleep,100
  send,sr
  return
+c::			;[Shift+C] トレンチ/Pioneer土嚢
  send,b
  sleep,100
  send,tg
  return
+f::			;[Shift+F] テラーマイン/TM-35/M6地雷
  send,b
  sleep,100
  send,m
  return
;=================================


;==マップスクロール==================
e::up			;[E] カメラ上
d::down			;[D] カメラ下
s::left			;[S] カメラ左
f::right		;[F] カメラ右
;=================================


;==マウス=========================
+MButton::			;[Shift+ホイールクリック] マップに印を付ける
  send,^a
  sleep,1
  send,{LButton}
  return
^RButton::			;[Ctrl+右クリックホールド] 家の中の歩兵をカーソル位置に出す
  While GetKeyState("RButton", "P")
  {
  send,{Tab}
  send,{RButton}
  }
  return
MButton::LAlt		;[ホイールクリック]  カメラの角度を変更
XButton1::u			;[マウス横ボタン1] 後退走行
XButton2::send,g	;[マウス横ボタン2] Attackground
;=================================


;==その他=========================
vkA2::Ctrl		;[CapsLock] CapsLockキーはCtrlとして動作。同時押しに使用
esc::F10			;[Esc]	メニュー
c::send,{Numpad0}	;[C]	戦略マップ
x::Esc				;[X]	選択解除
u::send,{Pause}		;[U]	ポーズ
^WheelUp::send,~	;[Ctrl+ホイールアップ] リプレイ再生速度+
^WheelDown::send,-	;[Ctrl+ホイールダウン] リプレイ再生速度-
^Tab::				;[Ctrl+Tab] リプレイ一時停止/再生
  MouseClick, , 880, 970
  MouseClick, , 580, 650
  return
^!a::send,^f		;[Ctrl+Alt+A] FoW切替
^!s::send,^@		;[Ctrl+Alt+S] Player Stats

^!z::				;[Ctrl+Alt+Z] ウィンドウを最大化
  WinSet, Style, -0xC40000, a
  WinMove, a, , 0, 0, % A_ScreenWidth, % A_ScreenHeight
  return
;=================================


;=================================
;誤動作防止のためのキー無効化
;=================================
LWin::return		;[Windowsキー]	Windowsキー無効化
vkF3::return	;[変換キー]		変換キー無効化
;=================================


;=================================
;無変換キーによる日本語チャット入力。
;現状無効にしてある(変換を押しても何も起こらない)のでチーム戦で日本語を入力したい場合は
;各行頭の ; を計6つ削除して下さい。CoH2上で日本語を使わないならこのままでOK。
;=================================
+vk1D::		;[Shift+無変換キー] 日本語チャットを開始する際に押す。AHKをOFFし、日本語入力をONしてチャットを開く
;  IME_SET(1)
;  send,{Enter}
;  Suspend,On
  return
vk1D::			;[無変換キー] チャット内容を書き終わり確定する際に押す。AHKをONし、日本語入力をOFFしてチャットを確定する
;  Suspend,Off
;  IME_SET(0)
;  send,{Enter}
  return
;=================================


;=================================
;  ■説明
;  このスクリプトはCoH2のゲーム内でのみ機能します。フォーカスが他のウィンドウの時は何もしません。
;  何を押すと何が起こるかは全てこのスクリプト内に書いてあります。熟読してください。
;  リプレイ名などテキストを書きたい場合はShift+Altで無効化する必要があります。Altで有効化します。
;  
;  CapsLockがCtrlキーとして機能するようにしてあります。Ctrlキーとの同時押しが多いためです。
;  都合が悪い場合は、「vkA2::Ctrl」の行頭に ; を入れてコメント化(無効化)してください。
;  
;  マウスサイドボタンに後退走行を割り当てています。サイドボタンがない場合はCtrl+Eで可能です。
;  ナンバリングは1〜6、QWRTが使用可能です。
;
;
;  ■キー割当の見方
;
;			^g::send,vf	;[Ctrl+G] Pファウスト/AP弾/煙幕手榴弾
;			 g::s		;[G] Stop
;		割当キー::起こる事	;→ここからは全て注釈(ただの説明)
;
;  「g::s」というのは、gを押したらgでなくsを押したことにするという意味で、これが一番シンプルな記述です。Sはストップの命令。
;  「^g::send,vf」というのは、Ctrl+gを押したら,「vf」と続けてキーボードに入力させる記述です。VとFのアビリティが選択されます。
;  2文字以上を入力させたい場合は「g::ng」というように書くとエラーになり、sendを使う必要があります。「,」の後に入力させるキーを。
;  EnterやAltキーの場合、{}で囲む必要があります。「send,Alt」と書くと「A→l→t」と1文字ずつ入力されます。
;
;  ShiftとCtrl、Altの3つを修飾キーと呼び、これを同時押しに使うことができます。ただしその場合は必ずsendを使う必要があります。
;  「+」でShift、「^」でCtrl、「!」でAltと同時押しということになります。(例: ^!z は Ctrl+Alt+Z同時押し)。
;  修飾キー有りと無しが混在する場合は、先に修飾キー有りのものを書いてください。(+gや^gよりも下側にgを書く)
;
;  gや^gの部分を変更すればキーの割当を変更できます。a〜z、1〜9が使えます。ただし重複がないようにしてください。
;
;  「b::b」のように同じキーを割り当てる場合、誤動作を防ぐため行頭に「;」を付けて注釈扱いにしてください。
;  「b::b」というのは全く無意味な記述なので別に消してしまっても問題はありません。操作説明として載せているだけです。
;
;  変更するのは「::」の左側の割当キーと、注釈だけにしてください。「起こる事」の部分を変更すると誤動作の元となります。
;  アビリティに関しては重複しないようにまとめてあります。これ以上合体させるとキー選択できないアビリティが出ます。
;  
;  1行で収まらない場合はreturnを最後に入れる必要があります。これはキー操作の終わりを表す命令です。
;  スクリプトを変更したら上書き保存して、タスクトレイ上のHアイコンを右クリックしてReloadで変更を適用できます。
;  もしスクリプトの動きがおかしくなった場合、同様にReloadしたりキーボード右側のShiftを押したり、このスクリプトを再起動して下さい。
;=================================