;一番下にキー割当の変更を含めたミニ解説があります。

#IfWinActive, Company Of Heroes 2		;CoH2上でのみ有効
#SingleInstance ignore					;2つ以上の起動を無効化
SetTitleMatchMode, 3

;==スクリプトの制御==================
~RShift::Suspend,On			;[右Shift]		このスクリプトを無効化。チャットを開始する際に押す
~RCtrl::Suspend,Off			;[右Ctrl]		このスクリプトを有効化。
;=================================

;==リプレイ・観戦時の制御==================
^WheelUp::send,~	;[Ctrl+ホイールアップ]	リプレイ 再生速度+
^WheelDown::send,-	;[Ctrl+ホイールダウン]	リプレイ 再生速度-
#a::send,:			;[Win+A]			リプレイ ユニットをフォロー
#s::send,^@			;[Win+S]			リプレイ Player Stats
#d::send,^{left}	;[Win+D]			リプレイ UI切替
#f::send,^f			;[Win+F]			リプレイ FoW切替
^Tab::				;[Ctrl+Tab]			リプレイ 一時停止/再生
  MouseClick, , 870, 990
  MouseClick, , 610, 715
  MouseClick, , 580, 650
  return
;=================================


;==グリッドホットキーをShift同時押下に設定し直し==
;==ZXVはShiftなしでそのままグリッドホットキーで動作=
+q::send,q			;[Shift+Q] Qキー Attack
+w::send,w			;[Shift+W] Wキー Stop
+e::send,e			;[Shift+E] Eキー AttackGround
+r::send,r			;[Shift+R] Rキー Reteat/BackGear
+a::send,a			;[Shift+A] Aキー 建設メニュー
+s::send,s			;[Shift+S] Sキー 建設メニュー/HoldFire
+d::send,d			;[Shift+D] Dキー PrioritizeViecle/HandBrake
+f::send,f			;[Shift+F] Fキー
+t::send,t			;[Shift+T] Tキー アップグレード1
+g::send,g			;[Shift+G] Gキー アップグレード2
+c::send,c			;[Shift+C] Cキー アビリティー3
;=================================


;==建造物建設=========================
^s::send,saq		;[Ctrl+S] 建造物1つ目
^d::send,saw		;[Ctrl+D] 建造物2つ目
^f::send,sae		;[Ctrl+F] 建造物3つ目
^e::send,sar		;[Ctrl+E] 建造物4つ目
^c::send,sa			;[Ctrl+C] 建造物5つ目
;=================================


;==マップスクロール==================
e::up				;[E] カメラ上
d::down				;[D] カメラ下
s::left				;[S] カメラ左
f::right			;[F] カメラ右
;=================================


;==部隊選択(ナンバリング)=============
;1〜4、QWRTAGがナンバリングとして使用可能
q::5
w::6
r::7
t::8
a::9
g::0
;=================================


;==マウス==========================
^MButton::send,^a{LButton}	;[Ctrl+ホイールクリック] マップに印を付ける
MButton::			;[ホイールクリック]	カーソル位置へアタックムーブで移動 ※Qキーを押しているため施設では生産キューが入る
  if (GetKeyState("Shift", "P"))
  {
  send,{RShift down}
  send,q{LButton}
  send,{RShift up}
  return
  }
  send,q{LButton}
  return
^RButton::			;[Ctrl+右クリックホールド] 家の中の歩兵をカーソル位置に出す
  While GetKeyState("RButton", "P")
  {
  send,{Tab}
  send,{RButton}
  }
  return
XButton1::r			;[マウス横ボタン1]	後退走行
XButton2::e			;[マウス横ボタン2]	Attackground
;=================================


;==メイン==========================
c::Numpad0			;[C]			戦略マップ
y::send,{Pause}		;[Y]			ポーズ
^v::send,{f 5}		;[Ctrl+V]		選択中の歩兵全補充
;=================================


;==その他=========================
vk1D & a::send,!{Enter}		;[無変換+A]	全画面切替
^!z::				;[Ctrl+Alt+Z]		ウィンドウを最大化
  WinSet, Style, -0xC40000, a
  WinMove, a, , 0, 0, % A_ScreenWidth, % A_ScreenHeight
  return
;=================================


;=================================
;誤動作防止のためのキー無効化
;=================================
;LWin::esc			;[Windowsキー]	WindowsキーをEscapeに
vkF3::return		;[変換キー]		変換キー無効化
vk1D::return		;[無変換キー]		無変換キー無効化
;=================================


;=================================
;  ■説明
;  このスクリプトはCoH2のゲーム内でのみ機能します。フォーカスが他のウィンドウの時は何もしません。
;  何を押すと何が起こるかは全てこのスクリプト内に書いてあります。熟読してください。
;  リプレイ名などテキストを書きたい場合はShift+Altで無効化する必要があります。Altで有効化します。
;  
;  CapsLockがCtrlキーとして機能するようにしてあります。Ctrlキーとの同時押しが多いためです。
;  都合が悪い場合は、「vkA2sc01D::Ctrl」の行頭に ; を入れてコメント化(無効化)してください。
;  
;  マウスサイドボタンに後退走行を割り当てています。
;
;
;  ■キー割当の見方
;
;			^g::send,vf	;[Ctrl+G] Pファウスト/AP弾/煙幕手榴弾
;			 g::s		;[G] Stop
;		割当キー::起こる事	;→ここからは全て注釈(ただの説明)
;
;  「g::s」というのは、gを押したらgでなくsを押したことにするという意味で、これが一番シンプルな記述です。Sはストップの命令。
;  「^g::send,vf」というのは、Ctrl+gを押したら,「vf」と続けてキーボードに入力させる記述です。VとFのアビリティが選択されます。
;  2文字以上を入力させたい場合は「g::ng」というように書くとエラーになり、sendを使う必要があります。「,」の後に入力させるキーを。
;  EnterやAltキーの場合、{}で囲む必要があります。「send,Alt」と書くと「A→l→t」と1文字ずつ入力されます。
;
;  ShiftとCtrl、Altの3つを修飾キーと呼び、これを同時押しに使うことができます。ただしその場合は必ずsendを使う必要があります。
;  「+」でShift、「^」でCtrl、「!」でAltと同時押しということになります。(例: ^!z は Ctrl+Alt+Z同時押し)。
;  修飾キー有りと無しが混在する場合は、先に修飾キー有りのものを書いてください。(+gや^gよりも下側にgを書く)
;
;  gや^gの部分を変更すればキーの割当を変更できます。a〜z、1〜9が使えます。ただし重複がないようにしてください。
;
;  「b::b」のように同じキーを割り当てる場合、誤動作を防ぐため行頭に「;」を付けて注釈扱いにしてください。
;  「b::b」というのは全く無意味な記述なので別に消してしまっても問題はありません。操作説明として載せているだけです。
;
;  変更するのは「::」の左側の割当キーと、注釈だけにしてください。「起こる事」の部分を変更すると誤動作の元となります。
;  アビリティに関しては重複しないようにまとめてあります。これ以上合体させるとキー選択できないアビリティが出ます。
;  
;  1行で収まらない場合はreturnを最後に入れる必要があります。これはキー操作の終わりを表す命令です。
;  スクリプトを変更したら上書き保存して、タスクトレイ上のHアイコンを右クリックしてReloadで変更を適用できます。
;  もしスクリプトの動きがおかしくなった場合、同様にReloadしたりキーボード右側のShiftを押したり、このスクリプトを再起動して下さい。
;=================================